TPTP Problem File: SWV491+4.p

View Solutions - Solve Problem

%------------------------------------------------------------------------------
% File     : SWV491+4 : TPTP v7.4.0. Released v4.0.0.
% Domain   : Software Verification
% Problem  : Matrix is identity
% Version  : Especial.
% English  :

% Refs     : [KV09]  Kovacs (2009), Email to Geoff Sutcliffe
% Source   : [KV09] 
% Names    : Id7 [KV09]

% Status   : Theorem
% Rating   : 0.69 v7.4.0, 0.57 v7.3.0, 0.66 v7.1.0, 0.65 v7.0.0, 0.73 v6.3.0, 0.62 v6.2.0, 0.72 v6.1.0, 0.77 v6.0.0, 0.78 v5.5.0, 0.85 v5.4.0, 0.89 v5.3.0, 0.93 v5.2.0, 0.85 v5.1.0, 0.90 v5.0.0, 0.96 v4.1.0, 1.00 v4.0.1, 0.87 v4.0.0
% Syntax   : Number of formulae    :   13 (   4 unit)
%            Number of atoms       :   47 (  15 equality)
%            Maximal formula depth :   11 (   5 average)
%            Number of connectives :   37 (   3   ~;   2   |;  17   &)
%                                         (   3 <=>;  12  =>;   0  <=)
%                                         (   0 <~>;   0  ~|;   0  ~&)
%            Number of predicates  :    3 (   0 propositional; 2-2 arity)
%            Number of functors    :    7 (   5 constant; 0-2 arity)
%            Number of variables   :   29 (   0 sgn;  28   !;   1   ?)
%            Maximal term depth    :    3 (   1 average)
% SPC      : FOF_THM_RFO_SEQ

% Comments :
%------------------------------------------------------------------------------
fof(int_leq,axiom,(
    ! [I,J] :
      ( int_leq(I,J)
    <=> ( int_less(I,J)
        | I = J ) ) )).

fof(int_less_transitive,axiom,(
    ! [I,J,K] :
      ( ( int_less(I,J)
        & int_less(J,K) )
     => int_less(I,K) ) )).

fof(int_less_irreflexive,axiom,(
    ! [I,J] :
      ( int_less(I,J)
     => I != J ) )).

fof(int_less_total,axiom,(
    ! [I,J] :
      ( int_less(I,J)
      | int_leq(J,I) ) )).

fof(int_zero_one,axiom,(
    int_less(int_zero,int_one) )).

fof(plus_commutative,axiom,(
    ! [I,J] : plus(I,J) = plus(J,I) )).

fof(plus_zero,axiom,(
    ! [I] : plus(I,int_zero) = I )).

fof(plus_and_order1,axiom,(
    ! [I1,J1,I2,J2] :
      ( ( int_less(I1,J1)
        & int_leq(I2,J2) )
     => int_leq(plus(I1,I2),plus(J1,J2)) ) )).

fof(plus_and_inverse,axiom,(
    ! [I,J] :
      ( int_less(I,J)
    <=> ? [K] :
          ( plus(I,K) = J
          & int_less(int_zero,K) ) ) )).

fof(one_successor_of_zero,axiom,(
    ! [I] :
      ( int_less(int_zero,I)
    <=> int_leq(int_one,I) ) )).

fof(real_constants,axiom,(
    real_zero != real_one )).

fof(qii,hypothesis,(
    ! [I,J] :
      ( ( int_leq(int_one,I)
        & int_leq(I,n)
        & int_leq(int_one,J)
        & int_leq(J,n) )
     => ( ! [C] :
            ( ( int_less(int_zero,C)
              & I = plus(J,C) )
           => ! [K] :
                ( ( int_leq(int_one,K)
                  & int_leq(K,J) )
               => a(plus(K,C),K) = real_zero ) )
        & ! [K] :
            ( ( int_leq(int_one,K)
              & int_leq(K,J) )
           => a(K,K) = real_one )
        & ! [C] :
            ( ( int_less(int_zero,C)
              & J = plus(I,C) )
           => ! [K] :
                ( ( int_leq(int_one,K)
                  & int_leq(K,I) )
               => a(K,plus(K,C)) = real_zero ) ) ) ) )).

fof(id,conjecture,(
    ! [I,J] :
      ( ( int_leq(int_one,I)
        & int_leq(I,n)
        & int_leq(int_one,J)
        & int_leq(J,n) )
     => ( ( I != J
         => a(I,J) = real_zero )
        & ( I = J
         => a(I,J) = real_one ) ) ) )).

%------------------------------------------------------------------------------